Создание сложной структуры XML

Как и с помощью чего можно в Delphi создать такую структуру XML файла? Подскажите пожалуйста, дайте примеры. Заранее спасибо.

Миниатюры

procedure BuildTree(const ARootDir : String; ANode : IXmlNode);
var
  Path : String;
  SearchRec : TSearchRec;
  ObjNode : IXmlNode;
begin
  Path := IncludeTrailingPathDelimiter( ARootDir );
  if FindFirst( Path + '*', faAnyFile, SearchRec ) = 0 then
    try
      repeat
        if ( SearchRec.Name = '.' ) or ( SearchRec.Name = '..' ) then Continue;

        ObjNode := ANode.AddChild( 'item' );
        ObjNode.Text := SearchRec.Name;

        if SearchRec.Attr and faDirectory <> 0 then
          begin
            ObjNode.SetAttributeNS( 'type', '', 'folder' );
            BuildTree( ARootDir + SearchRec.Name, ObjNode );
          end
        else
          ObjNode.SetAttributeNS( 'type', '', 'file' );
      until FindNext( SearchRec ) <> 0;
    finally
      FindClose( SearchRec );
    end;
end;

procedure SaveFolderTree(const AFolder, AFileName : String);
var
  Doc : IXMLDocument;
  RootNode : IXmlNode;
begin
  Doc := NewXMLDocument;
  try
    Doc.Options := [ doNodeAutoIndent ];
    Doc.Active := True;

    RootNode := Doc.AddChild( 'Items' );
    BuildTree( AFolder, RootNode );

    Doc.SaveToFile( AFileName );
  finally
    Doc := nil;
  end;
end;